{
  description = "OneChat";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default-linux";
  };

  outputs =
    {
      self,
      nixpkgs,
      systems,
    }:
    let
      forEachSystem = nixpkgs.lib.genAttrs (import systems);
      date = self.lastModifiedDate;
      revision = self.shortRev or self.dirtyShortRev or "unknown";
      version = "${builtins.substring 0 4 date}-${builtins.substring 4 2 date}-${builtins.substring 6 2 date}-${revision}";
    in
    {
      packages = forEachSystem (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          onechat = pkgs.callPackage ./nix/package.nix {
            src = self;
            inherit version;
          };
        in
        {
          inherit onechat;
          default = onechat;
        }
      );

      devShells = forEachSystem (system: {
        default = import ./nix/devshell.nix {
          pkgs = nixpkgs.legacyPackages.${system};
        };
      });

      checks = forEachSystem (system: {
        package = self.packages.${system}.default;
        replay = import ./nix/replay.nix { onechat = self.packages.${system}.default; };
        user-service = import ./nix/user-service-check.nix {
          pkgs = nixpkgs.legacyPackages.${system};
          onechat = self.packages.${system}.default;
        };
      });

      formatter = forEachSystem (system: nixpkgs.legacyPackages.${system}.nixfmt);
    };
}